Documentation

Aggregator' is the most general form of "aggregator", of which Aggregator and Aggregator1 are special cases. Aggregator's are comprised of aggregation functions and/or GROUP BY clauses.

Aggregation functions operating on individual Exprs such as sum can be combined into Aggregators operating on larger types using the Applicative, Profunctor and ProductProfunctor interfaces. Working with Profunctors can sometimes be awkward so for every sum we also provide a sumOn which bundles an lmap. For complex aggregations, we recommend using these functions along with ApplicativeDo, BlockArguments, OverloadedRecordDot and RecordWildCards:

data Input f = Input
  { orderId :: Column f OrderId
  , customerId :: Column f CustomerId
  , productId :: Column f ProductId
  , quantity :: Column f Int64
  , price :: Column f Scientific
  }
  deriving (Generic, Rel8able)


totalPrice :: Input Expr -> Expr Scientific
totalPrice input = fromIntegral input.quantity * input.price


data Result f = Result
  { customerId :: Column f CustomerId
  , totalOrders :: Column f Int64
  , productsOrdered :: Column f Int64
  , totalPrice :: Column f Scientific
  }
  deriving (Generic, Rel8able)


allResults :: Query (Result Expr)
allResults =
  aggregate
    do
      customerId <- groupByOn (.customerId)
      totalOrders <- countDistinctOn (.orderId)
      productsOrdered <- countDistinctOn (.productId)
      totalPrice <- sumOn totalPrice
      pure Result {..}
    do
      order <- each orderSchema
      orderLine <- each orderLineSchema
      where_ $ order.id ==. orderLine.orderId
      pure
        Input
          { orderId = order.id
          , customerId = order.customerId
          , productId = orderLine.productId
          , quantity = orderLine.quantity
          , price = orderLine.price
          }

An Aggregator takes a Query producing a collection of rows of type a and transforms it into a Query producing a single row of type b. If the given Query produces an empty collection of rows, then the single row in the resulting Query contains the identity values of the aggregation functions comprising the Aggregator (i.e., 0 for sum, false for or, etc.).

Aggregator is a special form of Aggregator' parameterised by Full.

An Aggregator1 takes a collection of rows of type a, groups them, and transforms each group into a single row of type b. This corresponds to aggregators using GROUP BY in SQL. If given an empty collection of rows, Aggregator1 will have no groups and will therefore also return an empty collection of rows.

Aggregator1 is a special form of Aggregator' parameterised by Semi.

Given a value to fall back on if given an empty collection of rows, toAggregator turns an Aggregator1 into an Aggregator.

toAggregator1 turns an Aggregator into an Aggregator1.