Hooks for observing or wrapping Redis I/O.

Hooks are installed through connect defaultConnectInfo { connectHooks = ... } and wrap the low-level actions used by hedis:

• sendRequestHook wraps regular command execution.
• sendPubSubHook wraps pub/sub command sending.
• callbackHook wraps invocation of pub/sub callbacks.
• sendHook wraps raw bytes sent to the server.
• receiveHook wraps reply reception.

The common pattern is to start from defaultHooks and override only the hook(s) you need. Each hook receives the original action and is expected to call it after performing any extra work such as logging, tracing, metrics, or timing.

Hooks can be used to alter existing behavior, or used to add metrics or telemetry to the redis application.

Example:

import Data.IORef
import Database.Redis

data Counts = Counts
  { sendRequestCount :: Word
  , sendCount :: Word
  , receiveCount :: Word
  }

hooks :: IORef Counts -> Hooks
hooks ref =
  defaultHooks
    { sendRequestHook = \run argv -> do
        modifyIORef ref $ \c -> c { sendRequestCount = sendRequestCount c + 1 }
        run argv
    , sendHook = \sendBytes bytes -> do
        modifyIORef ref $ \c -> c { sendCount = sendCount c + 1 }
        sendBytes bytes
    , receiveHook = \recvReply -> do
        modifyIORef ref $ \c -> c { receiveCount = receiveCount c + 1 }
        recvReply
    }

main :: IO ()
main = do
  ref <- newIORef (Counts 0 0 0)
  conn <- connect defaultConnectInfo { connectHooks = hooks ref }
  _ <- runRedis conn $ set "key" "value"
  readIORef ref >>= print