GenericPretty: A generic, derivable, haskell pretty printer.

*******************************************************************************
*     GenericPretty. 
*     A Generic, Derivable, Haskell Pretty Printer
*******************************************************************************

========================== Description ========================================

GenericPretty is a haskell library that provides support for automatic
derivation of pretty printing functions on user defined data types.

The Pretty library [1] is used underneath, the work is done over "Doc" types.

The library "MyPretty" is also provided. This library is a thin wrapper around 
the "Pretty" library and implements only "Style" related features. 
These features are planned to be added to the Pretty library itself. When 
that happens "MyPretty" will become obsolete and will be replaced by "Pretty".
  
The output provided by the library functions is identical to that of 
Prelude.show, except it has extra whitespace.
	
This library requires the use of the new GHC.Generics features [2]
These features are present in versions of GHC >= 7.2.

The Generics used are based on those described in the paper "A Generic Deriving
Mechanism for Haskell" - by Magalh�es, Dijkstra, Jeuring and L�h in Proceedings
of the third ACM Haskell symposium on Haskell (Haskell'2010), pp. 37�48, ACM, 
2010 [3]. 
There are however several changes between the mechanism described in 
the paper and the one implemented in GHC [4].

This generics mechanism supports deriving for all haskell datatypes EXCEPT for
constrained datatypes.
That is to say, datatypes which have a context will fail. For instance,
"data (Eq a) => Constr a = Constr a" will fail because of the (Eq a) context.

============================== Basic Example ==================================

Here is a haskell source file, called 'SimpleTest.hs'
----------------------------------------------------
{-# LANGUAGE DeriveGeneric #-}

import Text.PrettyPrint.GenericPretty

data Tree a = Leaf a | Node (Tree a) (Tree a) deriving (Generic)

instance (Out a) => Out (Tree a) where
	docPrec = genOut

tree1 :: Tree Int
tree1 = Node (Node (Leaf 333333) (Leaf (-555555)))(Node (Node(Node(Leaf 888888) 
		(Leaf 57575757))(Leaf (-14141414)))(Leaf 7777777))
			
main = pp tree1
------------------------------------------------
The flag DeriveGeneric must be given to GHC. This can be done as above, 
in a 'LANGUAGE' pragma, or manually by compiling with 'ghc -XDeriveGeneric'.

As can be seen, to use the library one must simply import it, derive 'Generic' 
on the custom data type, and write an instance of 'Out' using 'genOut'.

Then one can use the pretty printing functions, such as 'pp' and 'pretty'.

Compiling and running the file is simple and gives the following result.
-----------------------------
$ ghc SimpleTest.hs
$ SimpleTest

Node (Node (Leaf 333333) (Leaf (-555555)))
     (Node (Node (Node (Leaf 888888) (Leaf 57575757)) (Leaf (-14141414)))
           (Leaf 7777777))
---------------------------
If we replaced the main function with 'main = ppLen 30 tree1', 
the result would instead be:

Node (Node (Leaf 333333)
           (Leaf (-555555)))
     (Node (Node (Node (Leaf 888888)
                       (Leaf 57575757))
                 (Leaf (-14141414)))
           (Leaf 7777777))
		   
In this case the output tries to remain under 30 characters/line, if possible, 
while always maintaining correct indentation.

There also is a 'ppStyle' function which lets you further customize the output
by giving a 'Style' which consists of the line length, the number of ribbons 
per line and the mode to us.

A ribbon length is the length of non-indentation text per line.
So if I used a line length of 80 and 2 ribbons per line than I would have a
maximum of 40 non-indentation characters on any line.

The mode tells 'Pretty' how to render the result. There are 4 options:
1. PageMode - the default rendering
2. ZigZagMode - zig-zag cuts
3. LeftMode - there is no indentation and no maximum line length
4. OneLineMode - everything is put on one line	

The most interesting one is the ZigZagMode. Using the running example and adding:

--------------------------------------
zigStyle :: Style
zigStyle = Style {mode = ZigZagMode, lineLength = 30, ribbonsPerLine = 1.5}

main = ppStyle zigStyle tree1
--------------------------------------

We get the result:

Node (Node (Leaf 333333)

/////
      (Leaf (-555555)))
(Node (Node (Node (Leaf 888888)

/////
             (Leaf 57575757))
       (Leaf (-14141414)))
 (Leaf 7777777))

Notice that the "/" show us the direction in which the rows below have been moved
(left in this case) and the number of "/"s indicate the number of characters
that the rows were moved(in this case 5 characters to the left)

========================== Customization Example ==============================

Customizing the pretty printed results is also straightforward, as in the
following example called 'CustomTest.hs'
----------------------------
{-# LANGUAGE DeriveGeneric #-}

import Text.PrettyPrint.GenericPretty
import Text.PrettyPrint.MyPretty

data Tree a = Leaf a | Node (Tree a) (Tree a) deriving (Generic)

instance (Out a) => Out (Tree a) where
  docPrec n (Leaf a) =  parens $ text "customLeaf" <+> docPrec n a
  docPrec n (Node a b) = parens $ text "customNode" $$ nest 1 (docPrec n a) 
                                                    $$ nest 1 (docPrec n b)

tree1 :: Tree Int
tree1 = Node (Node (Leaf 333333) (Leaf (-555555)))(Node (Node(Node(Leaf 888888) 
		(Leaf 57575757))(Leaf (-14141414)))(Leaf 7777777))
			
main = pp tree1
------------------------------
Here we import the library 'MyPretty' and use it directly to define docPrec.
The syntax is the one used in both the Pretty[1] and the HughesPJ [5] libraries
By running the above we get a tree with a minimum of indentation:

(customNode
  (customNode
    (customLeaf 333333)
    (customLeaf -555555))
  (customNode
    (customNode
      (customNode
        (customLeaf 888888)
        (customLeaf 57575757))
      (customLeaf -14141414))
    (customLeaf 7777777)))

-----------------------------------

========================= Further Info ========================================

The above 'Tree' examples can be found in 'TestSuite/SimpleTest.hs' 
and 'TestSuite/CustomTest.hs'. More involved examples integrated 
with QuickCheck can be found in 'TestSuite/Tests.hs'.

Further information can be found in the API [6] and in the source code itself.

============================ Contact ==========================================

Please send any questions/suggestions to:
Razvan Ranca <ranca.razvan@gmail.com>

============================= Links ===========================================

[1] http://www.haskell.org/ghc/docs/7.0.4/html/libraries/ghc-7.0.4/Pretty.html
[2] http://www.haskell.org/haskellwiki/Generics
[3] http://dreixel.net/research/pdf/gdmh.pdf
[4] http://www.haskell.org/haskellwiki/Generics#Changes_from_the_paper
[5] http://hackage.haskell.org/packages/archive/pretty/1.1.0.0/doc/html/Text-PrettyPrint-HughesPJ.html
[6] http://hackage.haskell.org/packages/archive/GenericPretty/1.0.1/doc/html/Text-PrettyPrint-GenericPretty.html